7ca657d22f
Requires qt6-static, obviously... at least for eden. eden-cli also can be built fully static Notable challenges n such: 1. VkMemAlloc conflicts with Qt, since it embeds vk_mem_alloc.h in qrhivulkan; we can get around this by conditionally defining VMA_IMPLEMENTATION; that is, define it in the SDL2 frontend and undef it in the Qt frontend. It's not ideal, but I mean... it works, no? 2. find_library, pkgconfig, and some Config modules will always look for a .dll, so we have to tell CMake to look for .a 3. In spite of this, some will end up using .dll.a (implib) as their link targets; this is, well, bad, so we create a find_library hook that rejects dll.a 4. Some libraries have specific configs (boost lol) 5. Some libraries use _static targets (zstd, mbedtls) 6. Some extra libraries need to be linked, i.e. jbig, lzma, etc 7. QuaZip is sad Needs testing on all platforms, and for both frontends on desktop, to ensure Vulkan still works as expected. (also: CI). Resulting executables are: - 71MB for eden.exe - 39MB for eden-cli.exe Considering the entire libicudt is included (thanks Qt), that's a great size all things considered. No need to bundle all those plugins and translation files too. Theoretically, this lays the groundwork towards fully static executables for other platforms too; though Linux doesn't have a huge benefit since AppImages are needed regardless. eden-room though maybe? Fixes comp for clangarm64 because -msse4.1 Also allows macOS to build with qt6-static. macOS can't build static executables, but with these changes it ONLY relies on system libraries like libc and frameworks. So in theory we don't even need macdeployqt. Signed-off-by: crueter <crueter@eden-emu.dev> Reviewed-on: https://git.eden-emu.dev/eden-emu/eden/pulls/2994
40 lines
1.2 KiB
CMake
40 lines
1.2 KiB
CMake
# SPDX-FileCopyrightText: Copyright 2025 Eden Emulator Project
|
|
# SPDX-License-Identifier: GPL-3.0-or-later
|
|
|
|
# SPDX-FileCopyrightText: 2022 yuzu Emulator Project
|
|
# SPDX-License-Identifier: GPL-2.0-or-later
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
|
|
find_package(zstd QUIET CONFIG)
|
|
if (zstd_CONSIDERED_CONFIGS)
|
|
find_package_handle_standard_args(zstd CONFIG_MODE)
|
|
else()
|
|
find_package(PkgConfig QUIET)
|
|
pkg_search_module(ZSTD QUIET IMPORTED_TARGET libzstd)
|
|
find_package_handle_standard_args(zstd
|
|
REQUIRED_VARS ZSTD_LINK_LIBRARIES
|
|
VERSION_VAR ZSTD_VERSION
|
|
)
|
|
endif()
|
|
|
|
if (zstd_FOUND AND NOT TARGET zstd::zstd)
|
|
if (TARGET zstd::libzstd_shared AND NOT YUZU_STATIC_BUILD)
|
|
add_library(zstd::zstd ALIAS zstd::libzstd_shared)
|
|
elseif (TARGET zstd::libzstd_static)
|
|
add_library(zstd::zstd ALIAS zstd::libzstd_static)
|
|
else()
|
|
add_library(zstd::zstd ALIAS PkgConfig::ZSTD)
|
|
endif()
|
|
endif()
|
|
|
|
get_target_property(ZSTD_TARGET zstd::zstd ALIASED_TARGET)
|
|
|
|
if (NOT TARGET zstd::libzstd)
|
|
if (ZSTD_TARGET)
|
|
add_library(zstd::libzstd ALIAS ${ZSTD_TARGET})
|
|
else()
|
|
add_library(zstd::libzstd ALIAS zstd::zstd)
|
|
endif()
|
|
endif()
|